WIP

src/pipelines/eraser/eraser-agent.wgsl

@@ -0,0 +1,63 @@
+struct Settings {
+  eraserRadius: f32,
+  segmentCount: f32,
+  agentCount: f32,
+  eraserRadiusSquared: f32,
+};
+
+const MAX_SEGMENT_COUNT = 384u;
+
+@group(1) @binding(0) var<uniform> settings: Settings;
+@group(1) @binding(2) var<storage, read> segments: array<vec4<f32>>;
+
+@compute @workgroup_size(64)
+fn main(
+  @builtin(global_invocation_id) global_id: vec3<u32>,
+  @builtin(num_workgroups) workgroup_count: vec3<u32>
+) {
+  let id = get_id(global_id, workgroup_count);
+
+  if id >= u32(settings.agentCount) {
+    return;
+  }
+
+  var agent = agents[id];
+  if agent.colorIndex < 0.0 {
+    return;
+  }
+
+  for (var i = 0u; i < MAX_SEGMENT_COUNT; i++) {
+    if i >= u32(settings.segmentCount) {
+      break;
+    }
+
+    let segment = segments[i];
+    let distanceSquared = distanceSquaredFromLine(
+      agent.position,
+      segment.xy,
+      segment.zw
+    );
+
+    if distanceSquared <= settings.eraserRadiusSquared {
+      agent.position = vec2<f32>(-1.0, -1.0);
+      agent.targetPosition = vec2<f32>(-1.0, -1.0);
+      agent.colorIndex = -1.0;
+      agents[id] = agent;
+      return;
+    }
+  }
+}
+
+fn distanceSquaredFromLine(position: vec2<f32>, start: vec2<f32>, end: vec2<f32>) -> f32 {
+  let pa = position - start;
+  let direction = end - start;
+  let denominator = dot(direction, direction);
+
+  if denominator <= 0.0001 {
+    return dot(pa, pa);
+  }
+
+  let q = clamp(dot(pa, direction) / denominator, 0.0, 1.0);
+  let nearestOffset = pa - direction * q;
+  return dot(nearestOffset, nearestOffset);
+}